
В современном мире трудно найти область техники, где не применялись бы микропроцессоры. Они применяются при вычислениях, они выполняют функции управления, они используются при обработке звука и изображения. В зависимости от области применения микропроцессора меняются требования к нему. Это накладывает отпечаток на внутреннюю структуру микропроцессора. 
Микроконтроллеры объединяются в семейства. К одному семейству относят изделия, имеющие одинаковое ядро – совокупность таких понятий, как система команд, циклограмма работы ЦП, организация памяти программ и памяти данных, система прерываний и базовый набор периферийных устройств. Отличия между различными предста­вителями одного семейства заключаются, в основном, в составе периферийных устройств и объеме памяти программ или данных. 
 Одним из наиболее ранних микроконтроллеров, появившихся на рынке, является микроконтроллер 8051, разработанный фирмой Intel более двадцати лет назад. Несмотря на столь приличный возраст, классический 8051 и его клоны в настоящее время остаются одними из наиболее популярных при разработке систем управления и контроля. Хорошо продуманная архитектура и интуитивно понятная система команд оказывают решающее влияние на выбор многих разработчиков аппаратно-программных систем.
Микроконтроллеры линейки 8051 постоянно развиваются, предлагая разработчику все новые и новые возможности. На основе базового кристалла 8051 созданы и успешно применяются устройства с развитой периферией и большими объемами памяти.

В рамках реализации курсового проекта необходимо разработать микропроцессорную систему сбора и обработки информации, осуществляющую ввод информационного потока с одного периферийного устройства и обработку, и выдачу на два других периферийных устройства.
Устройство ввода – аналого-цифровой преобразователь, метод опроса по прерыванию (ADC).
Устройство вывода – жидкокристаллический индикатор (LCD modul).
Дополнительное устройство вывода - дисплей на семисегментных индикаторах.
Количество вводимых слов - 10.
Порядок ввода-вывода - FIFO.
Начальный адрес массива – 52h.
Тип данных - целые без знака.
Метод организации цикла – с предусловием.
Алгоритм обработки информационного массива – найти минимальное положительное число, большее 10.
Язык программирования: ассемблер MCS51.

Электронный симулятор EdSim51 представляет собой программную модель лабораторного стенда, построенного на основе МК 8051 и содержащего набор внешних периферийных устройств, наиболее часто используемых при построении микропроцессорных систем управления. Кроме того, электронный симулятор EdSim51 имеет в своем составе необходимый набор программных средств, предназначенных для разработки и отладки программного обеспечения МК.
Функциональная схема модели лабораторного стенда EdSim51 приведена на рисунке 1.
Стенд включает в себя следующие основные компоненты:
микроконтроллер 8051, являющийся ядром всей МПС;
схему подключения блока светодиодов (LED0…LED7), цифроаналогового преобразователя (ЦАП) (DAC) и дисплея на семисегментных светодиодных индикаторах (DISP0…DISP3); 
схему подключения блока светодиодов, ЦАП и жидкокристаллического (ЖК) индикатора (LCD modul); 
схему подключения блока механических переключателей (SW0…SW7) и аналого-цифрового преобразователя (АЦП) (ADC);
схему подключения компаратора (comparator) и ЦАП;
схему подключения электродвигателя (bridge driver, motor sensor) и универсального асинхронного приёмопередатчика (УАПП) (UART);
схему подключения клавиатуры матричного типа (keypad).
[image: logicDiagramBW]
Рисунок 1 - Функциональная схема модели лабораторного стенда                   EdSim51

Кроме того, стенд включает источник постоянного напряжения, линейно изменяющегося в диапазоне от 0 до +5В, служащего для формирования входных аналоговых сигналов (analog input voltage) и осциллограф (scope), предназначенный для контроля выходного сигнала ЦАП.
На рисунке 2 приведен внешний вид модели лабораторного стенда EdSim51, у которого можно выделить четыре основных панели, имеющих различное функциональное назначение:
панель микроконтроллера;
панель ассемблерного кода;
панель периферийного оборудования;
панель отображения состояния линий портов ввода/вывода микроконтроллера и их коммутации с периферийным оборудованием.

[image: ]
Рисунок 2 – Внешний вид модели лабораторного стенда EdSim51

Схема подключения блока механических переключателей и АЦП приведена на рисунке 3.
Когда ключ открыт логическая 1 поступает на контакт порта (через подтягивающий резистор), когда закрыт ключ соединяет контакт с землей - логический 0.
Блок ключей и выходов АЦП подключаются ко 2 порту. Из этого следует, что, когда используется АЦП, все ключи должны быть открыты (в симуляторе открытые ключи отмечены синим цветом).
Если ключ закрыт, то не важно, что АЦП пытается выдать по этой линии, на линии будет уровень логического 0, так как линия напрямую соединена с землей. 
[image: ]
Рисунок 3 – Схема подключения блока механических переключателей и АЦП

Схема подключения блока светодиодов и дисплея на семисегментных светодиодных индикаторах приведена на рисунке 4.
Как видно из рисунка 4, группа светодиодов и семисегментные индикаторы разделяют между собой порт Р1 МК 8051.
Выбор, какой из 4-х индикаторов активный осуществляется через контакты P3.3 и P3.4. Эти контакты порта подсоединены к дешифратору 2-4 (decoder), выходы которого подсоединяются к базе транзисторов и которые включают/выключают индикаторы соответственно уровнем логического нуля и уровнем логической единицы.
[image: ]
Рисунок 4 – Блок светодиодов и дисплей на семисегментных светодиодных индикаторах
Дешифратор включается в момент появления логической «1» на контакте P0.7. Этот контакт также подсоединён со входом WR ЦАП, даннй вход является инверсным, т.е. активным сигналом для него будет «0». Таким образом, чтобы записать данные в ЦАП программист отключает дисплеи, что активирует линии данных ЦАП. Когда на входе WR «0» всё что на входах ЦАП хранится (или записывается) во внутреннем регистре ЦАП и остается там, после того как на входе WR появляется «1». Аналоговый вывод для этих данных будет отображаться на экране осциллографа (scope), до тех пор, пока на входе WR вновь не окажется «0» и новое значение не запишется во внутренний регистр.

Схема подключения блока светодиодов, ЦАП и ЖК-индикатора приведена на рисунке 5.
[image: ]
[bookmark: _Ref95634951]Рисунок 5 – Схема подключения блока светодиодов, ЦАП и ЖК-индикатора
Пользователь может переключаться между семисегментным индикатором и ЖК - модулем, как показано на рисунке, нажав на синюю кнопку над дисплеем (рисунок 5).
[image: ]
Рисунок 5 - Выбор между семисегментным индикатором и ЖК - модулем
ЖК – модуль является моделью популярного индикатора Hitachi HD44780. Модуль сопрягается с микроконтроллером 8051 в 4-х битном режиме работы. Контакты P1.4 - Р1.7 подключены к DB4-DB7, а контакт P1.3 подключен к контакту регистра выбора (register-select), контакт P1.2 подключен к контакту разрешения (Enable).
Так как симулятор работает не в режиме реального времени, то на модели трудно реализовать режим мигания символов. Поэтому, режим мигания имитируется режимом изменения цвета символов и фона, в котором происходит чередование синего текста на красном фоне с красным текстом на синем фоне. Таким образом, пользователь с первого взгляда может определить, что модуль находится в режиме мигания (когда режиме мигания не включен все символы отображаются черным цветом на сером фоне).
Контакт разрешения E (Enable), подключенный к P1.2 срабатывает по спадающему фронту. По спадающему фронту на контакте E модуль считывает данные с DB4-DB7.
4-х битный режим. Как видно из схемы, модуль сопряжен с микроконтроллером 8051 в 4-х битном режиме. Это означает что контакты модуля DB0, DB1, DB2 и DB3 не используются. 8-ми битовые инструкции или данные должны быть отправлены в 2-х полубайтах (по 4 бита). Старший полубайт отправляется первым, за ним следует младший. Когда на контакте разрешения происходит смена активного сигнала на пассивный (спадающий фронт), модуль начинает считывать информацию с контактов DB4-DB7 и хранит их или в IR, если посылается инструкция (RS=0) или в DR, если посылаются данные (RS=1). Изначально модуль находится в 8-ми битном режиме работы и должен быть переведен программистом в 4-х битный, прежде чем выполнять какие либо действия. Это можно сделать, отправив соответствующую инструкцию (Function Set).
Так как первая инструкция, направленная в модуль читается как 8-битная инструкция (как будто разряды DB3 - DB0 используются), то если отправлена корректная инструкция (с DL на DB4, с указанием 4-х бит), модуль «знает», что он установлен на 4-х битные операции и читает инструкции и данные в двух полубайтах (по 4 бита). 
Неверная инструкция Function Set Программист должен установить модуль в 4-х битный режим работы, 2-строчный, 5 х 8 шрифт. Моделирование работы HD44780 осуществляется только в таком режиме. Если режим установлен неправильно, то будет отображено сообщение об ошибке (Рисунок 6). 
[image: ]
[bookmark: _Ref95634918]Рисунок 6 – Неверная инструкция Function Set

Разработка алгоритма программного обеспечения для поиска минимальное положительное число, большее 10, заключается в разделении большой задачи на меньшие подзадачи. 
В данном курсовом проектировании можно выделить 2 основных составляющих алгоритма: алгоритм опроса АЦП по прерыванию, который также включает в себя запись в память вычисленного значения, и алгоритм поиска минимального числа в соответствии с заданием на курсовое проектирование. Далее, в подразделах, подробнее будут рассмотрены выделенные составляющие.

	Для обработки прерывания, необходимо разрешить все внешние прерывания и прерывания для работы с АЦП. 
Организация цикла с предусловием, поэтому проверка увеличение счетчика адреса и декремент счетчика элементов будет на один раз больше. Для корректной работы необходимо завысить и занизить соответствующие значения при инициализации.
В цикле ожидается нажатие и отжатие кнопки в соответствии с номерами варианта. Если элементы закончились, то выход из цикла, запрещение прерывания от АЦП и возврат из подпрограммы ввода. Если элементы остались, то переход к соответствующей метке. Далее необходимо запустит АЦП с переднего фронта на входе WR.
	При возникновении прерывания управление передается на 03H адрес. Там находится команда безусловного перехода на подпрограмму обработки прерывания, так как вся подпрограмма может не уместится на адресе 03H. В подпрограмме обработке прерывания необходимо отключить высокоимпедансное состояние у АЦП, чтобы считать его значения на порте P2. При этом все SW0…SW7 должны быть отжаты, иначе результат работы АЦП будет неверным. После считывания значений с порта P2, происходит запись числа в память, включение высокоимпедансного состояния у АЦП и выход из подпрограммы обработки прерывания.

Алгоритм поиска минимального положительного числа, больше 10, реализован с помощью арифметических команд, команд операций над битами и передачи управления микроконтроллера 8051.
Система команд семейства MCS-51 содержит 111 базовых команд, которые по функциональному признаку можно подразделить на пять: 
пересылки данных; 
арифметических операций; 
логических операций; 
операций над битами; 
передачи управления. 
Формат команд - одно-, двух- и трехбайтовый, причем большинство команд (94) имеют формат один или два байта. Первый байт любых типа и формата всегда содержит код операции, второй и третий байты содержат либо адреса операндов, либо непосредственные операнды. 
Состав операндов включает в себя операнды четырех типов: биты, 4-бита (4 разряда), байты и 16- битные слова. Время исполнения команд составляет 1, 2 или 4 машинных цикла. При тактовой частоте 12 мГц длительность машинного цикла составляет 1 мкс, при этом 64 команды исполняются за 1 мкс, 45 команд - за 2 мкс и 2 команды (умножение и деление) - за 4 мкс.
Блок-схема алгоритма приведена на рисунке 7. Разрядность регистров 1 байт. Проход осуществляется по всем элементам массива, начиная с младшего адреса. Если элементов в массиве больше нет, выход из подпрограммы выполнения алгоритма. Чтобы проверить число является, больше 10 или нет необходимо из этого числа вычесть 11. Если возник заем из старшей части, то это значит, что число меньше или равно 10, в противном случае число больше 10. Далее необходимо проверить, число является минимальным, из всех обработанных. Для этого из регистра, в котором сохраняется самое минимальное число, найденное в предыдущих итерациях, вычитается из аккумулятора, в котором находится текущее значение. Если возникает заем из старшей части, это значит, что число в аккумуляторе было меньше. Необходимо сохранить число в регистр результата и продолжить цикл. Если заема из старшей части не было, значит число в аккумуляторе больше, поэтому переход к следующему числу или выход из цикла, если все элементы пройдены.
[image: ]
[bookmark: _Ref95636072]Рисунок 7 – Алгоритм поиска минимального положительного числа

[bookmark: _Toc93499961][bookmark: _Toc93927191][bookmark: _Toc95216786][bookmark: _Toc95641100][bookmark: _Toc95641155]4   Разработка программы

В рамках курсового проектирования была разработана программа поиска минимального положительного числа, больше 10. Программа реализована в соответствии с алгоритмом, описанным в пункте 3.

Для обработки прерывания, необходимо разрешить все внешние прерывания и прерывания INT0, установив 1 биты EA и EX0. 
Организация цикла с предусловием, поэтому проверка увеличение счетчика адреса и декремент счетчика элементов будет на один раз больше. Для корректной работы необходимо завысить и занизить соответствующие значения при инициализации.
В цикле ожидается нажатие и отжатие кнопки на порте P2.1. Если элементы закончились, то выход из цикла, запрещение прерывания от INT0 и возврат из подпрограммы ввода. Если элементы остались, то переход к соответствующей метке. Далее необходимо запустит АЦП с помощью бита порта P3.6. Необходимо сделать передний фронт сбросом и установкой этого бита. После этого для корректной работы необходимо сделать небольшую задержку, однако это не обязательно, так как частота работы микроконтроллера достаточно высокая и пользователь не успеет повторно нажать кнопку запуска.
При возникновении прерывания INT0 управление передается на 03H адрес. 
ORG 0				
	JMP MAIN	
ORG 3					; Переход, если прерывание INT0
	JMP EXT0ISR			; Переход на подрограмму	
Там находится команда безусловного перехода на подпрограмму обработки прерывания, так как вся подпрограмма может не уместится на адресе 03H. В подпрограмме обработке прерывания необходимо отключить высокоимпедансное состояние у АЦП, чтобы считать его значения на порте P2. При этом все SW0…SW7 должны быть отжаты, иначе результат работы АЦП будет неверным. После считывания значений с порта P2, происходит запись числа в память, включение высокоимпедансного состояния у АЦП и выход из подпрограммы обработки прерывания. 
	CLR P3.7			; Отключение SW0-7
	MOV @R0, P2		; Копирование P2 в память
	INC R0			; Переход к следующей ячейке
	SETB P3.7			; Включение SW0-7
Уменьшение указателя массива и количества оставшихся символов. В постусловии проверяется количество оставшихся символов. Если символов не осталось, то происходит выход из подпрограммы алгоритма.  

[bookmark: _Toc93499963][bookmark: _Toc93927193][bookmark: _Toc95216788][bookmark: _Toc95641102][bookmark: _Toc95641157]4.2   Разработка программы поиска минимального положительного числа

В результате циклического опроса переключателей, в память микроконтроллера записаны 10 чисел, над которыми производятся вычисления по поиску минимальных положительных чисел, больше 10.
Таким образом, в результате 10 итераций происходит чтение значений из памяти и их сравнение. Чтобы проверить число является, больше 510 или нет необходимо из этого числа вычесть 11. Если возник заем из старшей части, то это значит, что число меньше или равно 10, в противном случае число больше 10. 
	CLR C
	SUBB A, #11		; больше или равно 11 условие
	JC CYCLE2		; проверка флага с
Далее необходимо проверить, число является минимальным, из всех обработанных. Для этого из регистра, в котором сохраняется самое минимальное число, найденное в предыдущих итерациях, вычитается из аккумулятора, в котором находится текущее значение. Если возникает заем из старшей части, это значит, что число в аккумуляторе было меньше. Необходимо сохранить число в регистр результата и продолжить цикл. Если заема из старшей части не было, значит число в аккумуляторе больше, поэтому переход к следующему числу или выход из цикла, если все элементы пройдены.
	JNC CYCLE2		; проверка флага с
	MOV A, @R0
	MOV R2, A			; сохранение найденного значения	
В случаях, если ни одного числа не найдено, на семисегментную индикацию выводится “Err”, что обозначает, что все числа не удовлетворяют условиям поиска. Для определения ошибки используется пользовательский флаг F0. Если хотя бы одно минимальное число было найдено, то флаг будет установлен. Иначе, если флаг не был установлен, то вывод ошибки. Если же значение было найдено, оно выводится на блок жидкокристаллического индикатора.

Для запуска программного обеспечения необходимо открыть симулятор EdSim51 и скомпилировать разработанный код (Рисунок 8). [image: ]
[bookmark: _Ref95638688]Рисунок 8 – Компиляция разработанного кода в симуляторе EdSim51

Старт программы осуществляется с помощью кнопки Run на панели инструментов. Далее при нажатии и отжатии любой кнопки клавиатуры происходит чтение числа с переключателей, обработка числа, и его запись в память микроконтроллера ().
[image: ]
Рисунок 9 – Обработка числа, полученного с АЦП, и его запись в память микроконтроллера

После фиксации в памяти 10 чисел, полученных с переключателей, выполняется подпрограмма поиска четных чисел, удовлетворяющих условиям задания на курсовое проектирование. На рисунке 10 показан вывод найденного значения, а на рисунке 11 показан вывод ошибки на семисегментную индикацию.

Рисунок 10 – Вывод минимального числа в R2 и БЖКИ, размещение данных в памяти

[bookmark: _Toc93499965][bookmark: _Toc93927195][bookmark: _Toc95216790]Рисунок 11 – Вывод ошибки на семисегментную индикацию

В соответствии с рисунками 10 и 11 были произведены контрольные просчеты, покрывающие положительные и отрицательные варианты работы алгоритма.

Последовательный ввод чисел: 1.6V, 4.64V, 3.56V, 0.00V, 0.21V, 0.19V, 0.98V, 1.96V, 3.11V, 0,35V.
Запись в память: 53h, EDh, B6h, 00h, 0Bh, 0Ah, 32h, 64h, 9Fh, 12h.
Из полученной последовательности, наименьшее положительное число, больше 10, – 0Bh. Результат работы – 0Bh. Это значение мы можем наблюдать в регистре R2 и окне LCD модуля (рисунок 10). 

Последовательный ввод чисел: 0.19V, 0.17V, 0.15V, 0.13V, 0.11V, 0.09V, 0.07V, 0.05V, 0.03V, 0.01V.
Запись в память: 0Ah, 09h, 08h, 07h, 06h, 05h, 04h, 03h, 02h, 01h.
В полученной последовательности, все числа меньше или равны 10. Результат работы – FF, флаг F0 сброшен. Таким образом, на семисегментной индикации должно появиться сообщение об ошибке «Err».

[bookmark: _Toc93499968][bookmark: _Toc93927131][bookmark: _Toc93927198][bookmark: _Toc95290682][bookmark: _Toc95641107][bookmark: _Toc95641162]7   Разработка схемы электрической структурной

С учетом поставленной задачи, была разработана структурная схема, представленная на чертеже Э1 (приложении Б).
В соответствии со структурной схемой, напряжение подается на основные блоки проектируемого устройства, то есть на блок управления семисегментной индикации (БУССИ), блок аналого-цифрового преобразователя (БАЦП), блок сброса (БС), блок механических переключателей (БМП) и на блок микроконтроллера (БМК).
После начала работы, устройство ожидает нажатие клавиши в БМП, после чего данные передается от БАЦП в БМК, где записывается в память для дальнейшей работы с ним. Данное действие производится 10 раз в соответствии с заданием на курсовое проектирование.
Поиск минимального положительного числа, больше 10 осуществляется после завершения процедуры сканирования и записи идентифицированных значений в память. Данный алгоритм осуществляется программным обеспечением, записанным в БМК и основанным на простых битовых и логических операциях. В результате успешного поиска, вычисленное значение передается для индикации на блок жидкокристаллического индикатора, которые связаны с портом Р1 БМК. В результате неуспешного поиска, в работу вступает БУССИ и непосредственно БССИ, на который передается «ключевое слово» об ошибке выполнения алгоритма, т.е. искомое значение не было найдено – «Err».

В пунктах 3, 7 данной пояснительной записки были рассмотрены функциональные особенности разрабатываемого устройства. На основании этих данных разработана принципиальная схема микропроцессорной системы сбора и обработки информации, осуществляющей ввод информационного потока с одного периферийного устройства и обработку, и выдачу на два других периферийных устройства. 
В соответствии с заданием, при построении принципиальной схемы в данном курсовом проектировании необходимо ориентироваться на применение цифровых элементов серии ТТЛ.
Интегральные микросхемы ТТЛ (транзисторно-транзисторная логика) представляют собой микросхемы малой степени интеграции, выполненные на биполярных транзисторах.

Для переключателя необходим токоограничивающий резистор, чтобы не возникло короткого замыкания. Номинал резистора рассчитывается исходя из максимально протекающего тока. Максимальный ток, который способен выдать порт MCS51 – 2 мА. Таким образом, при напряжении питания 5В, по закону Ома, рассчитывается значение сопротивления участка цепи:
R = U / I
R = 5 / 0,002
R = 2500 Ом
Итак, минимально допустимый для использования номинал резистора – 2500 Ом. В то же время, чтобы стягивающий/подтягивающий резистор, не оказывал влияния на остальные участки цепи при замыкании (эффект делителя напряжения), рекомендуется выбирать несколько больший номинал 10 кОм.

Для питания входной цепи усилителя требуется напряжения +5В, которое может быть сформировано из заданного напряжения питания 2В с использованием микросхем стабилизаторов напряжения типа 78L05.
Керамические конденсаторы с ёмкостью в несколько десятых долей микрофарады (в данном случае C=0,047мкФ) стабилизирует работу микросхемы. Его ёмкость определена техническим описанием используемой микросхемы.

Микросхема KCSA02-105 включает в себя 4 семисегментных индикаторов с зелеными светодиодами, прямой ток которых равен 30 мА, а прямое напряжение 2 В. Таким образом, пользуясь техническими данными, рассчитаем значения резисторов R4-R11 следующим образом:
U = 5 В; Uд = 2 В; Iд = 0,03 А
R = (U – Uд) / Iд
R = (5 – 2) / 0,03
R = 100 Ом
Итак, расчетное сопротивление составляет 100 Ом, при этом стандартное значение резисторов 100 Ом. В соответствии с расчетом, подобраны резисторы R4-R11 с номиналом 100 Ом.
Для расчета резисторов R12 – R15 транзисторных ключей VT1-VT4 воспользуемся следующей формулой
Iбазы = Iнаг. / h, 
где для p-n-p транзисторов КТ814A коэффициент усиления равен 100, а ток нагрузки равен 8*0,02=0,16 А. исходя из этого, рассчитаем значение тока базы.
Iбазы = 0,16 / 100
Iбазы = 0,0016 А= 1,6 мА
Зная значение тока базы, сопротивление резистора вычисляется по следующей формуле (падение напряжения составляет 0,7В):
Uб = (Uн.п. – Uбэ)
Uб = 5 – 0,7
Uб = 4,3
где Uн.п. – напряжение питания, а Uбэ – напряжение базы эмиттера.
R = (Uб – U0) / Iб
R = (4,3 - 0) / 0,0016
R =2687 Ом
В соответствии с расчетом, подобраны резисторы R12 – R15 с номиналом 2,7 кОм.

Принципиальная схема устройства предложена на чертеже Э3 (приложение В).
Проектируемая микропроцессорная система сбора и обработки информации содержит: микроконтроллер КР1816ВЕ51, блок механических переключателей и клавиатура SW0-SW16, ADC0804, LCD module HD44780, импортный стабилизатор напряжения STU 78L05, дешифратор К555ИД4 и семисегментный светодиодный индикатор.
Блок сброса:
резисторы R1 и R2;
переключатель SW1;
конденсатор C7. 
Блок синхронизации и управления:
кварцевый резонатор ZQ1;
конденсаторы C8 и C9. 
Блок стабилизации напряжения:
микросхема DA1;
конденсаторы С1 – С6. 
Блок управления семисегментным индикатором:
дешифратор DD2;
резисторы R12 – R15;
транзисторы VT1 – VT4. 
Блок семи сегментного индикатора:
резисторы R4-R11;
микросхема HG2. 
Блок механических переключателей:
переключатели SW2;
резисторы R3.
Блок аналогово-цифрового преобразователя:
микросхема DA2.
Блок жидкокристаллического индикатора:
микросхема HG1.
Устройство работает в соответствии с алгоритмами, описанными выше. 

В ходе выполнения курсового проектирования была разработана микропроцессорная система сбора и обработки информации, осуществляющая ввод информационного потока с одного периферийного устройства и обработку, и выдачу на два других периферийных устройства. С помощью данной микропроцессорной системы осуществляется ввод с АЦП с помощью прерывания и поиск минимального положительного числа, удовлетворяющих условиям задания на курсовое проектирование. Данная система была смоделирована в симуляторе EdSim51.
К пояснительной записке прилагаются структурная и принципиальная схемы микропроцессорной системы, листинг программы и перечень элементов.

ORG 0				
	JMP MAIN	
ORG 3					; Переход, если прерывание INT0
	JMP EXT0ISR			; Переход на подрограмму	
ORG 30H			
MAIN:
	CALL INPUTDAC
	CALL FIND
	CALL OUTPUTDAC
JMP $

;====================================
; подпрограмма ввода чисел
INPUTDAC:
	
	MOV R0, #52H
	MOV R1, #11			; установка начального адреса

	SETB EX0			; Разрешение внешнего прерывания
	SETB EA				; Разрешение всех прерываний

	CYCLE:
		DJNZ R1, START	; предусловие
		CLR EX0			; Запрещение внешнего прерывания
		RET				; выход из процедуры
	START:
		JB	P2.1, $		; нажатие
		JNB	P2.1, $		; отжатие
		CLR P3.6		; Запуск АЦП
		SETB P3.6		; По переднему фронту
		CALL delay2	
	JMP CYCLE
	
;=======================
; Подпрограмма обработки прерывания
EXT0ISR:
	CLR P3.7			; Отключение SW0-7
	MOV @R0, P2			; Копирование P2 в память
	INC R0				; Переход к следующей ячейке
	SETB P3.7			; Включение SW0-7
	RETI


;====================================
; подпрограмма поиска 
FIND:
	MOV R0,#51H 		; адрес записи = (52h) - 1
	MOV R1,#11 			; счетчик для вводимых значений
	MOV R2,#255			; 
	CLR F0
	
	CYCLE2:
		INC R0
		DJNZ R1, START2	; предусловие
		RET				; выход из процедуры
	START2:
		MOV A, @R0	
		CLR C
		SUBB A, #11		; больше или равно 11 условие
		JC CYCLE2		; проверка флага с
		
		MOV A, @R0	
		SETB C
		SUBB A, R2		; вычитание
		JNC CYCLE2		; проверка флага с
		
		MOV A, @R0
		MOV R2, A		; сохранение найденного значения	
		SETB F0
	JMP CYCLE2

;========================
; 
OUTPUTDAC:
	
	JB F0, MODULE
	MOV P1, #0FFH
	SETB P0.7			; переключение на семисегментный
ERR1:

	CLR P3.3
	SETB P3.4
	MOV P1, #10000110B	; E
	MOV P1, #0FFH

	SETB P3.3
	CLR P3.4
	MOV P1, #11001110B	; R
	MOV P1, #0FFH

	CLR P3.3
	MOV P1, #11001110B	; R
	MOV P1, #0FFH
		
	JMP ERR1
	
MODULE:	
	
	MOV R0, #70H
	MOV @R0, #30H	; 0
	INC R0
	MOV @R0, #31H	; 1 
	INC R0
	MOV @R0, #32H	; 2
	INC R0
	MOV @R0, #33H	; 3
	INC R0
	MOV @R0, #34H	; 4
	INC R0
	MOV @R0, #35H	; 5
	INC R0
	MOV @R0, #36H	; 6
	INC R0
	MOV @R0, #37H	; 7
	INC R0
	MOV @R0, #38H	; 8
	INC R0
	MOV @R0, #39H	; 9
	INC R0
	MOV @R0, #41H	; A
	INC R0
	MOV @R0, #42H	; B
	INC R0
	MOV @R0, #43H	; C
	INC R0
	MOV @R0, #44H	; D
	INC R0
	MOV @R0, #45H	; E
	INC R0
	MOV @R0, #46H	; E
	
	CALL INITLCD
	CALL PRINTLCD
	
RET



;========================
; 00101010	- 4-битная передача 2 линии
; 00000110	- инкремент и сдвиг (off)
; 00001111	- нстройка курсора, дисплея
INITLCD:

	CLR P1.3			; Очистить RS - указывает, что инструкции отправляются на модуль
	;-------------------
	
	CLR P1.7			; 0010xxxx	- 4-битная передача
	CLR P1.6		
	SETB P1.5		
	CLR P1.4			; Набор старшей части байта
	
	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта
	
	;-------------------
	CALL delay2			; Ожидание очищения буффера	
	;-------------------
	
	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта
				
	SETB P1.7			; установка младшей части байта (нужно изменить только P1.7)	xxxx1010

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта
	
	;-------------------
	CALL delay2			; Ожидание очищения буффера
	;-------------------
	
	CLR P1.7			; |	0000xxxx
	CLR P1.6			
	CLR P1.5			
	CLR P1.4			; Набор старшей части байта

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта

	SETB P1.6			; xxxx0110
	SETB P1.5			; Набор младшей части байта
	;SETB P1.4			; сдвиг экрана
	
	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта
	
	;-------------------
	CALL delay2			; Ожидание очищения буффера
	;-------------------
	
	CLR P1.7			; 0000xxxx
	CLR P1.6		
	CLR P1.5		
	CLR P1.4			; Набор старшей части байта

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта

	SETB P1.7			; xxxx1111
	SETB P1.6		
	SETB P1.5		
	SETB P1.4			; Набор младшей части байта

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта
	
	;-------------------
	CALL delay2			; Ожидание очищения буффера
	;-------------------	
	
	SETB P1.7			; 1010xxxx
	CLR P1.6		
	CLR P1.5		
	CLR P1.4			; Набор старшей части байта

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта

	CLR P1.7			; Набор младшей части байта xxxx0000

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта
	
	;-------------------
	CALL delay2			; Ожидание очищения буффера
	;-------------------	
	
	SETB P1.7			; 1010xxxx
	CLR P1.6		
	CLR P1.5		
	SETB P1.4			; Набор старшей части байта

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта

	CLR P1.7			; xxxx0000
	CLR P1.4			; Набор младшей части байта

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта
	
	;-------------------
	CALL delay2			; Ожидание очищения буффера
	;-------------------	
	
	SETB P1.3			; Очистить RS - указывает, что данные отправляются в модуль
	CALL CLEARLCD		; очистить экран lcd
	CLR C				
	CALL LINE1LCD		; установить курсор в начальное положение, так как с = 0
	
	RET
	
	;========================
; Вывод на lcd одного символа по адресу из R0
PRINTLCD:

	MOV A, R2	
	ANL A, #0F0H
	SWAP A
	ADD A, #70H
	MOV R0, A
	MOV A, @R0
	
	MOV C, ACC.7	
	MOV P1.7, C		
	MOV C, ACC.6		
	MOV P1.6, C			
	MOV C, ACC.5	
	MOV P1.5, C		
	MOV C, ACC.4		
	MOV P1.4, C			; Набор старшей части байта

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта

	MOV C, ACC.3		
	MOV P1.7, C			
	MOV C, ACC.2		
	MOV P1.6, C			
	MOV C, ACC.1		
	MOV P1.5, C			
	MOV C, ACC.0		
	MOV P1.4, C			; Набор младшей части байта

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта

	;-------------------
	CALL DELAY2			; Ожидание очищения буффера
	;-------------------

	MOV A, R2	
	ANL A, #0FH
	ADD A, #70H
	MOV R0, A
	MOV A, @R0
	
	MOV C, ACC.7	
	MOV P1.7, C		
	MOV C, ACC.6		
	MOV P1.6, C			
	MOV C, ACC.5	
	MOV P1.5, C		
	MOV C, ACC.4		
	MOV P1.4, C			; Набор старшей части байта

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта

	MOV C, ACC.3		
	MOV P1.7, C			
	MOV C, ACC.2		
	MOV P1.6, C			
	MOV C, ACC.1		
	MOV P1.5, C			
	MOV C, ACC.0		
	MOV P1.4, C			; Набор младшей части байта

	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта

	;-------------------
	CALL DELAY2			; Ожидание очищения буффера
	;-------------------
	
RET	
	
		
;========================	
; Задержка для LCD
DELAY2:
	MOV R7, #50
	DJNZ R7, $
	RET
	
	;========================
; новая строка LCD
Line1LCD:
	CLR P1.3			; Очистить RS - указывает, что инструкции отправляются на модуль
	
	SETB P1.7			; 0000xxxx	- 4-битная передача
	MOV P1.6, C			; Если С = 1, то нижня строка (40H), если С = 0, то начало (00H)
	CLR P1.5		
	CLR P1.4			; Набор старшей части байта
	
	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта
	
	;----------
	CALL delay2			; Ожидание очищения буффера
	;----------
		
	CLR P1.7			; Набор младшей части байта
	CLR P1.6			
	
	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта
	
	;----------
	CALL delay2			; Ожидание очищения буффера
	;----------	
		
	SETB P1.3			; Очистить RS - указывает, что данные отправляются в модуль
		
	RET
	
	;========================
; Очищение LCD 0000 0001
CLEARLCD:
	CLR P1.3			;  Очистить RS - указывает, что инструкции отправляются на модуль

	CLR P1.7			; 0000xxxx	- 4-битная передача
	CLR P1.6		
	CLR P1.5		
	CLR P1.4			; Набор старшей части байта
	
	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта
	
	;----------
	CALL delay2			; Ожидание очищения буффера
	;----------
	
	SETB P1.4			; абор младшей части байта xxxx0001
	
	SETB P1.2			; Формирование переднего фронта
	CLR P1.2			; Формирование задниего фронта
	
	;----------	
	MOV R5, #255		; Задержка для очищения
CC2:		
	MOV R7, #255
	DJNZ R7, $	
	DJNZ R5, cc2	
	;----------
	
	SETB P1.3			;  Очистить RS - указывает, что инструкции отправляются на модуль
	RET

